무한서고

delay함수 없이 LED 깜빡이기

가끔씩 우리는 아두이노에서 병렬처리(한번에 두 가지 이상의 작업을 동시에 수행하는 것)가 필요할 때가 있습니다.
아두이노의 loop는 사실상 ms단위로 작동하기 때문에 구문을 나열해도 거의 동시에 처리되는 것처럼 보이긴 합니다.
그렇기에 평상시에는 크게 병렬처리에 대해서 생각할 필요가 없는데요.
그러나 LED핀을 깜빡이는데 가장 간편하게 사용하는 delay()함수가 들어가게 되면, 여기서부터 골치가 아파집니다.
왜냐하면 delay()함수를 사용하게 되면 아두이노가 프로그램을 일시 중지되기 때문이죠.
따라서 delay()함수가 작동하게 되면 지정한 시간만큼 프로그램이 일시 중지되고, 그 사이에는 다른 구문을 작동할 수가 없습니다.
예를들어 delay()함수 작동 중 버튼 눌림 체크가 불가능 하다거나, 다른 명령어 작동이 불가능하죠.

오늘 올릴 포스팅은 delay()함수를 사용하지 않고 LED를 깜박이는 방법에 대해 작성할 겁니다.

간단하게 개요부터 말씀드리자면,
1) delay()를 사용하지 않고
2) LED를 켜고(끄고) 시간(ms 단위)을 기록하고(millis() 함수)
3) 이 시간이 원하는 시간이 지났는지 확인하고
4) 시간이 지났으면 LED를 끕(켭)니다.

이렇게되면, delay()로 아두이노를 일시중지 시키지 않고 loop()함수가 살아서 계속 반복적인 작업이 이루어지므로 LED가 깜빡거리는 동안 다른 작업이 가능해집니다.

쉬운 예시로 전자레인지에 피자데우기를 들 수 있습니다.
자, 전자레인지에 피자를 넣고 전자레인지를 작동시킵니다.
여기서
1) delay()함수로 10초간 기다리라고 하는 말의 의미는 전자레인지 앞에서 10초가 다 지나가기를 가만히 기다리라는 의미입니다. 결국 그동안에 다른 일은 못하죠!
2) 그러나 우리가 만약에 두가지 일을 하고 싶다면 어떻게 하나요? 전자레인지에는 시간 카운터가 달려있기에 전자레인지를 돌리고 짧은시간 다른 용무를 보고와서 전자레인지 시계를 확인하고, 10초가 지났는지 확인하고, 만약 10초가 지났으면 꺼내서 먹으면 됩니다!

1. 배선

우리는 아주 간단하게 실험해 볼 것이므로 내장된 Blink예제를 사용해보도록하죠!(즉, 따로 배선이 필요 없습니다)
Blink예제는 >>링크<< 포스팅에서 다루었습니다. 링크의 포스팅을 따라 블링크 예제를 불러와봅시다!

2. 코딩

블링크 예제의 코드는 아래와 같습니다.(상단의 주석부분은 제거하였습니다.)

// 보드의 파워나 리셋 버튼을 눌렀을 때 이 setup 함수는 한번만 작동합니다.
void setup() {
  // digital pin인 LED_BUILTIN을 output으로 초기화 합니다.
  pinMode(LED_BUILTIN, OUTPUT);
}

// 이 loop 함수는 계속 계속 영원히 반복하여 작동합니다.
void loop() {
  digitalWrite(LED_BUILTIN, HIGH);  // LED 켜기 (HIGH는 전압 레벨)
  delay(1000);                      // 1초간 기다리기
  digitalWrite(LED_BUILTIN, LOW);   // 전압을 LOW로 설정하여 LED 끄기
  delay(1000);                      // 1초간 기다리기
}

자, 여기서 delay(1000) 즉, 1초간 아무것도 안하고 아두이노한테 기다리라고 하는 부분을 바꿔봅시다!

위의 예시에서 전자레인지의 시간만 중간중간 확인 가능하다면, 굳이 전자레인지 앞에서 지켜보고 있을 필요가 없다고했죠?
그러니 시간을 확인할 수 있는 함수를 알아봅시다!

millis()라고 하는 함수는 아두이노가 실행된 시점부터 내부적으로 카운팅하고 있는 밀리초의 시간을 반환하는 함수입니다.
즉, 이 millis()를 쓰면 중간중간 시간확인이 가능하다는 말이죠!

프로그램의 골자를 생각해봅시다.
1) 전자레인지를 돌리고 시간을 본다 => LED를 켜고 millis()로 시간을 확인한다(변수에 저장한다)
2) 시간을 확인한다 => 현재 시간이 처음 LED를 켠 시간에 비해 얼마나 지났는지 확인한다(현재시간 - LED 켠 시간)
3) 정해진 시간이 지났으면 피자를 꺼내먹는다 => [(현재시간 - LED 켠 시간) > 정해진 시간]이면 LED를 끈다

간단하죠? loop함수 내부 로직을 아래와 같이 짜봅시다.

// 1)
unsigned long startMillis;

digitalWrite(LED_BUILTIN, HIGH);
startMillis = millis();
// 2)&3)
if(millis()-startMillis >= 1000){
  startMillis = millis();
  digitalWrite(LED_BUILTIN, LOW);
}

자, 모든 조건을 만족하게 프로그래밍을 이렇게 하면... 작동하지 않습니다!
왤까요?
loop함수는 아두이노가 작동하는한 끊임없이 반복된다고 했습니다.
그런데 이 loop함수 내부에서 시작한 시간을 변수에 저장시키면, 매 loop함수가 작동할 때마다 변수에 새로운 값이 저장되기에 정확히 시작한 시간을 알 수 없죠!
그러면 대안은? 가장간단한건 loop함수 밖에서 시작시간을 설정해주거나, loop내에서도 일정한 조건일 때만 변수에 값을 넣어주는 겁니다.
게다가 loop함수 내부에서 digitalWrite(LED_BUILTIN, HIGH) 구문이 있기때문에 사실 LED_BUILTIN은 계속 켜져있을 겁니다.
일단은 가장 간단하게 갑시다! loop함수 밖에서 시작시간과 LED 켜기를 설정해줍시다.

unsigned long startMillis = millis(); // 전역변수는 함수 밖에 있어야 합니다.

void setup() {
  // digital pin인 LED_BUILTIN을 output으로 초기화 합니다.
  pinMode(LED_BUILTIN, OUTPUT);
  // 1)
  digitalWrite(LED_BUILTIN, HIGH);
}

// 이 loop 함수는 계속 계속 영원히 반복하여 작동합니다.
void loop() {
  if(millis()-startMillis >= 1000){
    startMillis = millis();
    digitalWrite(LED_BUILTIN, LOW);
  }
}

자, 이러면 작동합니다!
그러나 딱 한번만 작동합니다!
왤까요?
말그대로
1] 시작하면서 LED켜고 시간측정해!
2] 타이머가 1초가 지나가면 꺼!
끝이기 때문이죠. 1초가 지나면 꺼진상태가 그대로 유지됩니다.
그러면 어떻게 이 친구를 깜빡거리게(토글) 할 수 있을까요?
가장 간단한건 '1초일땐 꺼, 2초일땐 켜, 3초일땐 꺼...'지만, 이러면 모든 시간을 다 기록해줘야하죠..?
조금 더 머리를 써 봅시다.
지금 현재 LED 상태를 기억했다가 1초가 됐을 때 현재 LED상태를 보고 반대상태로 만들어주면 매 초마다 코딩을 하지 않아도 되지 않을까요!?
바로 실험해봅시다!

// 전역변수는 함수 밖에 있어야 합니다.
bool ledState; // led상태를 알 수 있는 변수를 하나 만듭니다. bool은 int와 다르게 참/거짓의 딱 두가지 값만 가질 수 있습니다. 우리는 결국 led가 켜졌냐/꺼졌냐 만 사용할 것이므로 bool을 사용합니다.
unsigned long startMillis = millis(); // 그리고 led 상태를 기록한 시간을 기록합시다.

void setup() {
  // digital pin인 LED_BUILTIN을 output으로 초기화 합니다.
  pinMode(LED_BUILTIN, OUTPUT);
  // 1)
  ledState = HIGH; // 그리고 바로 led를 켜지 말고, '상태'를 입력해주죠. 현재 led는 '켜짐상태'입니다.
}

// 이 loop 함수는 계속 계속 영원히 반복하여 작동합니다.
void loop() {
  if(millis()-startMillis >= 1000){ // led상태를 기록한 시간(startMillis)와 현재 시간(millis())를 비교해서 1초(1000ms)가 지났는지 판단합니다. 지났으면 if문 안으로! 만약 1초가 지나지 않았으면 이 if문은 통과합니다!
    if(ledState == HIGH){ // 현재 led상태를 확인합니다. 현재 led가 '켜짐상태'이면 '꺼짐상태'로, '꺼짐상태'이면 '켜짐상태'로 바꿔줄 겁니다.
      ledState = LOW; // 현재 led 상태가 '켜짐상태'였기에 '꺼짐상태'로 바꿔줍니다.
    }
    else{ // 아니면! 즉, 현재 led상태가 '꺼짐상태' 면
      ledState = HIGH; // 현재 led 상태를 '켜짐상태'로 바꿔줍니다.
    }
    startMillis = millis(); // 그리고 상태를 바꿔줬으니 바로 상태를 기록한 시간을 다시 기록합니다.
  }

  digitalWrite(LED_BUILTIN, ledState); // 마지막으로 '상태'를 LED에 진짜로 반영해줍니다!
}

자, 이 구문은 제대로 잘 작동합니다! 1초마다 LED_BUILTIN이 켜졌다 꺼졌다 하는군요!
전체적으로 작동로직을 한번 살펴볼까요?
처음 시작하면 setup함수 내부에서 LED를 '켜짐상태'로 설정하고, 그 시간을 기록합니다.
그리고 loop함수로 넘어오죠.
loop함수에서는 시작한시간과 현재시간을 비교하는데, 시작하고 1초도 지나지 않았습니다.
따라서 첫 if문은 바로 통과!
그 이후 loop함수 마지막에 digitalWrite로 LED_BUILTIN에 실제적으로 '상태'를 반영해줍니다.
결국 LED는 켜지고, 1초뒤에 첫번째 if문 안으로 들어갑니다.
첫번째 if문 안에서 현재 led상태가 HIGH이므로 두번째 if문으로 들어가 ledState를 LOW로 바꿔주고, 상태를 바꾼 시간을 다시 기록하고 if문을 빠져나와 digitalWrite로 LED_BUILTIN에 실제적으로 '상태'를 반영해줍니다.
그리고 이 반복이죠!

3. 더 나아가기

사실 위의 프로그램(스케치)은 loop함수 작동시마다 계속 digitalWrite를 부릅니다. 즉, 1초마다 한번씩만 바꿔주면 되는걸, 1초가 되기 전에 계속 '켜 켜 켜 켜 켜 켜 켜 켜'하고 반복신호를 주는거죠.(그리고 사실 이게 병렬처리가 되는 이유기도 합니다. 시간 체크하는 동안 계속해서 신호를 주는거죠.)
1초마다 신호를 주고, 더 짧은 코드를 공개합니다.
이번엔 주석을 지울테니 보고 더 생각해보세요!

bool ledState = LOW;
unsigned long startMillis = millis();

void setup() {
  pinMode(LED_BUILTIN, OUTPUT);
}

void loop() {
  if(millis()-startMillis >= 1000){
    digitalWrite(LED_BUILTIN, ledState=!ledState);
    startMillis = millis();
  }
}

함수설명: delay()

설명:

매개변수로 지정된 시간(밀리초(millisecond, ms)) 동안 프로그램을 일시 중지합니다. (1초(s)는 1000밀리초(ms)입니다.)

문법(syntax):

delay(ms)

매개변수(parameters):

ms: 일시 중지할 시간(밀리초)입니다. 허용되는 데이터 유형: unsigned long(부호없는 정수).

리턴값(returns):

없음

예제 코드:

이 코드는 출력 핀을 토글하기 전에 프로그램을 1초 동안 일시 정지합니다.

int ledPin = 13; // 디지털 핀 13에 연결된 LED

void setup() {
  pinMode(ledPin, OUTPUT); // 디지털 핀을 출력으로 설정합니다.
}

void loop() {
  digitalWrite(ledPin, HIGH); // LED를 켭니다.
  delay(1000); // 1초간 기다립니다.
  digitalWrite(ledPin, LOW); // LED를 끕니다.
  delay(1000); // 1초간 기다립니다.
}

참고:

delay() 함수로 깜박이는 LED를 쉽게 만들 수 있고 많은 스케치에서 스위치 디바운싱과 같은 작업에 짧은 지연을 사용하지만, 스케치에서 delay()을 사용하면 상당한 단점이 있습니다. delay 함수 작동 중에는 센서 판독, 수학적 계산 또는 핀 조작을 계속할 수 없으므로 사실상 대부분의 다른 활동이 중단됩니다. 타이밍 제어에 대한 다른 접근 방식은 충분한 시간이 경과할 때까지 millis() 함수를 폴링하여 반복하는 >>delay함수 없이 LED 깜빡이기<<를 참조하십시오. 일반적으로 Arduino 스케치가 매우 간단하지 않는 한 10밀리초 이상의 이벤트 타이밍에 delay()함수를 사용하지 않습니다.

그러나 delay() 함수가 인터럽트를 비활성화하지 않기 때문에 delay() 함수가 Atmega 칩을 제어하는 동안에도 특정 작업이 계속 진행됩니다. RX 핀에 나타나는 직렬 통신이 기록되고, PWM(아날로그 쓰기) 값과 핀 상태가 유지되며, 인터럽트가 정상적으로 작동합니다.

함수설명:digitalWrite()

설명:

디지털 핀에 HIGH(1) 또는 LOW(0) 값을 기록합니다.
핀이 pinMode()를 사용하여 출력으로 구성된 경우, 해당 전압은 HIGH의 경우 5V(또는 3.3V 보드의 경우 3.3V), LOW의 경우 0V(접지)로 설정됩니다.
input 모드로 설정된 핀에 대하여 사용 시 pullup 저항을 활성화 하지만, 가능하면 명시적인 INPUT_PULLUP을 사용하여 설정할 것을 추천드립니다.

문법(syntax):

digitalWrite(pin, value)

매개변수(parameters):

pin: 출력모드로 설정 된 아두이노 핀 번호
value: HIGH(1) 혹은 LOW(0)

리턴값(returns):

없음

예제 코드:

이 코드는 디지털 핀 13을 OUTPUT으로 설정하고, HIGH와 LOW로 토글(toggle, 전환)합니다.

void setup() {
pinMode(13, OUTPUT); // 디지털 핀 13을 OUTPUT으로 설정
}

void loop() {
digitalWrite(13, HIGH); // 디지털 핀 13을 on으로 설정
delay(1000); // 1초 기다리기
digitalWrite(13, LOW); // 디지털 핀 13을 off로 설정
delay(1000); // 1초 기다리기
}

참고:

위의 예제 코드에서 //(슬래시 두개)는 주석(컴파일 시 실제 코드로 인식 하지 않겠다는 의미)이며, 다른 글에서 설명하겠지만, delay() 함수는 말 그대로 '기다리는'함수이며, 그 안에 들어가는 값은 밀리세컨드 단위입니다. 즉 1000ms=1s 입니다.
아날로그 입출력 또한 가능합니다.
아날로그 입력의 경우 A0, A1 등으로 표시된 핀에서 가능하고, 출력은 ~(틸드)표시가 붙은 디지털 핀에서 가능합니다.
또한 반대로 아날로그 출력 핀(A0, A1, etc)을 디지털 핀으로 활용도 가능합니다.
예외적으로 아두이노 나노, 프로미니, 미니의 A6과 A7 핀은 오로지 아날로그 입력 핀으로만 사용할 수 있습니다.